We make a lot of relatively thin, flat parts, many of which are in a high-nickel ferrous alloy (so they're a pain to machine well) and many of which have tight tolerances on the thickness and/or flatness of the large sides. Because the parts are thin, the thickness tends to vary a bit across the part, and in order to check it thoroughly we would take points directly opposite each other in a dozen or more places and report the distance between them. It worked (and still works) great on our TP20 systems. However, we recently purchased a Global S 9-12-8 with a scanning head, and are hoping to use the scanning functionality to speed up our measuring routines considerably. In order to do the same "point-to-point" thickness measurement, we need to be able to identify particular hits that are opposite each other so we can dimension to them using the scn.hit notation. Here's a sketch:
I was about to post a screenshot of an actual part, and then realized it was ITAR. No good. Imagine the curvy series of green points comprising a scan on one side of a part, and the red series a scan on the other. What I'm trying to do is report the thickness between the points inside of each of the purple circles.
Is there any way to get PC-DMIS to do something like this automatically?
Having exhausted my own attempts to find a positive answer to that question, I wrote a subroutine to do it:
SUBROUTINE/SCANTHICK,
SCN1 = : THE FIRST SCAN,
SCN2 = : THE SECOND SCAN,
UCENT = : THE U-COORDINATE (X OR Y) OF THE SEARCH ZONE CENTER,
VCENT = : THE V-COORDINATE (Y OR Z) OF THE SEARCH ZONE CENTER,
PLANE = : "XY" "XZ" or "YZ",
RADIUS = : RADIUS AROUND CENTER IN WHICH TO SEARCH,
TOLERANCE = : MAXIMUM ACCEPTABLE (IN-PLANE) DISTANCE BETWEEN FOUND POINTS,
NOMINAL = : NOMINAL THICKNESS BETWEEN SCANS,
PLUSTOL = : PLUS TOLERANCE ON THICKNESS,
MINUSTOL = : MINUS TOLERANCE ON THICKNESS,
=
$$ NO,
Convert to UV coordinates
IF/PLANE=="XY"
ASSIGN/U1=SCN1.HIT[1..SCN1.NUMHITS].X
ASSIGN/V1=SCN1.HIT[1..SCN1.NUMHITS].Y
ASSIGN/U2=SCN2.HIT[1..SCN2.NUMHITS].X
ASSIGN/V2=SCN2.HIT[1..SCN2.NUMHITS].Y
END_IF/
ELSE_IF/PLANE=="XZ"
ASSIGN/U1=SCN1.HIT[1..SCN1.NUMHITS].X
ASSIGN/V1=SCN1.HIT[1..SCN1.NUMHITS].Z
ASSIGN/U2=SCN2.HIT[1..SCN2.NUMHITS].X
ASSIGN/V2=SCN2.HIT[1..SCN2.NUMHITS].Z
END_ELSEIF/
ELSE_IF/PLANE=="YZ"
ASSIGN/U1=SCN1.HIT[1..SCN1.NUMHITS].Y
ASSIGN/V1=SCN1.HIT[1..SCN1.NUMHITS].Z
ASSIGN/U2=SCN2.HIT[1..SCN2.NUMHITS].Y
ASSIGN/V2=SCN2.HIT[1..SCN2.NUMHITS].Z
END_ELSEIF/
ELSE/
COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
Subroutine SCANTHICK: Invalid Plane argument given! Exiting.
ROUTINE/END
END_ELSE/
$$ NO,
Identify points within search radius
ASSIGN/GOOD_I_SCN1=ARRAY(-1)
ASSIGN/K=1
ASSIGN/I=1
WHILE/I<=SCN1.NUMHITS
IF/SQRT((U1[I] - UCENT)^2 + (V1[I] - VCENT)^2) < RADIUS
ASSIGN/GOOD_I_SCN1[K]=I
ASSIGN/K=K+1
END_IF/
ASSIGN/I=I+1
END_WHILE/
IF/GOOD_I_SCN1[1] == -1
COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
Subroutine SCANTHICK: No valid SCN1 points found within search radius. Exiting.
ROUTINE/END
END_IF/
ASSIGN/GOOD_I_SCN2=ARRAY(-1)
ASSIGN/K=1
ASSIGN/I=1
WHILE/I<=SCN1.NUMHITS
IF/SQRT((U2[I] - UCENT)^2 + (V2[I] - VCENT)^2) < RADIUS
ASSIGN/GOOD_I_SCN2[K]=I
ASSIGN/K=K+1
END_IF/
ASSIGN/I=I+1
END_WHILE/
IF/GOOD_I_SCN2[1] == -1
COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
Subroutine SCANTHICK: No valid SCN2 points found within search radius. Exiting.
ROUTINE/END
END_IF/
$$ NO,
Brute force search for minimum distance (in UV plane)
ASSIGN/SMALLEST_SO_FAR=RADIUS*2
ASSIGN/SMALLEST_SCN1=-1
ASSIGN/SMALLEST_SCN2=-1
ASSIGN/ILOOP=1
WHILE/ILOOP <= LEN(GOOD_I_SCN1)
ASSIGN/I=GOOD_I_SCN1[ILOOP]
ASSIGN/JLOOP=1
WHILE/JLOOP <= LEN(GOOD_I_SCN2)
ASSIGN/J=GOOD_I_SCN2[JLOOP]
ASSIGN/DISTANCE=SQRT((U1[I] - U2[J])^2 + (V1[I] - V2[J])^2)
WORKPLANE/ZPLUS
IF/DISTANCE < SMALLEST_SO_FAR
ASSIGN/SMALLEST_SO_FAR=DISTANCE
ASSIGN/SMALLEST_SCN1=I
ASSIGN/SMALLEST_SCN2=J
END_IF/
ASSIGN/JLOOP=JLOOP+1
END_WHILE/
ASSIGN/ILOOP=ILOOP+1
END_WHILE/
IF/SMALLEST_SCN1 == -1 OR SMALLEST_SCN2 == -1
COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
Subroutine SCANTHICK: No points closer than radius*2 were found (???). Exiting.
ROUTINE/END
END_IF/
$$ NO,
Check if we've satisfied the result tolerance and output result
IF/SMALLEST_SO_FAR > TOLERANCE
COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
Subroutine SCANTHICK: Closest pair of points found were further apart than the tolerance. Exiting.
ROUTINE/END
END_IF/
IF/PLANE=="XY"
WORKPLANE/XPLUS
DIM DIST1= 2D DISTANCE FROM SCN1.HIT[SMALLEST_SCN1] TO SCN2.HIT[SMALLEST_SCN2] PAR TO ZAXIS,NO_RADIUS UNITS=IN,$
GRAPH=OFF TEXT=OFF MULT=10.00 OUTPUT=BOTH
AX NOMINAL +TOL -TOL MEAS MAX MIN DEV OUTTOL
M NOMINAL PLUSTOL MINUSTOL 0.0000 0.0000 0.0000 0.0000 0.0000 #-------
END_IF/
ELSE_IF/PLANE=="XZ"
WORKPLANE/XPLUS
DIM DIST2= 2D DISTANCE FROM SCN1.HIT[SMALLEST_SCN1] TO SCN2.HIT[SMALLEST_SCN2] PAR TO YAXIS,NO_RADIUS UNITS=IN,$
GRAPH=OFF TEXT=OFF MULT=10.00 OUTPUT=BOTH
AX NOMINAL +TOL -TOL MEAS MAX MIN DEV OUTTOL
M NOMINAL PLUSTOL MINUSTOL 0.0000 0.0000 0.0000 0.0000 0.0000 #-------
END_ELSEIF/
ELSE/
WORKPLANE/YPLUS
DIM DIST3= 2D DISTANCE FROM SCN1.HIT[SMALLEST_SCN1] TO SCN2.HIT[SMALLEST_SCN2] PAR TO XAXIS,NO_RADIUS UNITS=IN,$
GRAPH=OFF TEXT=OFF MULT=10.00 OUTPUT=BOTH
AX NOMINAL +TOL -TOL MEAS MAX MIN DEV OUTTOL
M NOMINAL PLUSTOL MINUSTOL 0.0000 0.0000 0.0000 0.0000 0.0000 #-------
END_ELSE/
ENDSUB/
An example of the calling code would be:
CS2 =CALLSUB/SCANTHICK,"SCAN_THICKNESS":{SCNA},{SCN_FRONT_TOP},-2.37,-.46,"XZ",.05,.01,.243,.0015,.0015,$
,
Here, SCNA has 784 points and SCN_FRONT_TOP has 206. The dimensions are in inches.
Frustratingly, this is super-slow to execute. I have to call it for each intersection I want to find, and each call takes about 2 minutes to complete. My latest program only has four points, which I'm dealing with for now, but some of our stuff has closer to 30 point-to-point measurements if not more.
Unless I find another way, I'll mess around with this a bit longer and then see if the algorithm above runs much faster in Visual Basic. Though, in that case, if I end up needing to use file IO and it takes more than a few seconds to read the entire scan out and back in, I'll be up a creek.
In conclusion:
- Does anyone know of a way within PC-DMIS to do what I'm trying to do without coding it myself?
- If not, does anyone see any major performance issues with my code that I should address?
- If not either of those, can anyone tell me if Visual Basic will be substantially better?
P. S. Another potential option would be to use this or something similar the first time, and then hard-code the hit indices for production. But that would stink if I ever need to change scan parameters for something and shift the points a bit. Also, are hits guaranteed to stay in the same spot from one run to the next even with the same parameters?
Attached Files
